From e331e95e3f3607bd1707b60f61e209e4aeac05f6 Mon Sep 17 00:00:00 2001
From: Irene Knapp <ireneista@irenes.space>
Date: Sat, 6 Sep 2025 15:06:48 -0700
Subject: initial package of kaylee

Force-Push: working CI? that's unpossible
Change-Id: I03dfbbcff92f2166616d26d4c3d556261a327d8b
---
 flake.nix | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 flake.nix

(limited to 'flake.nix')

diff --git a/flake.nix b/flake.nix
new file mode 100644
index 0000000..d81cb77
--- /dev/null
+++ b/flake.nix
@@ -0,0 +1,59 @@
+{
+  inputs = {
+    nixpkgs = {
+      type = "github";
+      owner = "NixOS";
+      repo = "nixpkgs";
+      ref = "nixos-25.05";
+    };
+  };
+
+  outputs = { self, nixpkgs }:
+  let supportedSystems = [ "aarch64-linux" "x86_64-linux" ];
+      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+      nixpkgsFor = forAllSystems (system: import nixpkgs { inherit system; });
+  in {
+    packages = forAllSystems (system: let pkgs = nixpkgsFor.${system}; in rec {
+      kaylee = pkgs.python3Packages.buildPythonPackage rec {
+        pname = "KayleeVC";
+        version = "0.1.1";
+
+        src = pkgs.fetchFromGitHub {
+          owner = "Ratfink";
+          repo = "kaylee";
+          rev = "baeb0e1fa08fb6b21e4a22458de16b4948d1f2d0";
+          hash = "sha256-ghZnmdtXme0g+nsi/dSGxQ6UqGB48lUhYaTSLF94KIo=";
+        };
+
+        patches = [
+          ./data-location.patch
+        ];
+
+        nativeBuildInputs = with pkgs; [
+          gobject-introspection
+          wrapGAppsHook4
+        ];
+
+        propagatedBuildInputs = (with pkgs; [
+          gtk3
+          pocketsphinx.lib
+        ]) ++ (with pkgs.gst_all_1; [
+          gstreamer
+          gst-plugins-base
+          gst-plugins-good
+        ]) ++ (with pkgs.python3Packages; [
+          requests
+          pygobject3
+        ]);
+      };
+    });
+
+    devShells = forAllSystems (system: let pkgs = nixpkgsFor.${system}; in {
+      default = pkgs.mkShell {
+        nativeBuildInputs = with pkgs; [
+        ];
+      };
+    });
+  };
+}
+
-- 
cgit 1.4.1